LOCAL graph

graph=0; // Código del gráfico del proceso

Esta variable predefinida es LOCAL, lo que significa que cada proceso tendrá su propio valor en su variable graph.

Normalmente, la mayoría de procesos se corresponden con un objeto gráfico visualizado en pantalla que se situará en las coordenadas indicadas en las variables locales x e y. Se debe definir qué gráfico es el correspondiente a dicho proceso asignando un código de gráfico a la variable local graph.

Por defecto, esta variable valdrá 0 lo que implica que no se visualizará ningún gráfico para este proceso.

Los gráficos se deben crear primero en el editor gráfico de DIV Games Studio (con la opción "Nuevo..." del menú de mapas) y, después, se pueden guardar en un archivo MAP o PCX (que contendrá este gráfico), o en un fichero FPG junto a otros gráficos (se puede crear un fichero nuevo con la opción "Nuevo..." del menú de ficheros).

Es decir, los gráficos utilizados en un programa pueden provenir de un archivo MAP o PCX (que contiene un sólo gráfico) o de un fichero FPG (que puede contener muchos gráficos).

Nota: Un mismo gráfico puede ser utilizado por muchos procesos a la vez en un programa.

Archivos MAP o PCX

Para utilizar en el programa un gráfico de un archivo MAP o PCX se debe cargar este llamando a las funciones load_map() o load_pcx(), que devolverán el código del gráfico que se debe ser asignado a la variable graph.

Normalmente se utiliza una variable GLOBAL para guardar este código de gráfico y después se asigna ésta a la variable graph.

Programa ejemplo: 
PROGRAM ejemplo_graph;

GLOBAL
    gráfico1;

BEGIN
    gráfico1=load_map("help\help.map");

    graph=gráfico1; // Se define el gráfico del proceso.

    LOOP
        x=mouse.x;
        y=mouse.y;
        FRAME;
    END
END


Si bien en el ejemplo anterior se podría haber prescindido de la variable global gráfico1 y haber asignado directamente el código devuelto por la función load_map() a la variable graph con la siguiente sentencia:

  graph=load_map("help\help.map");

los códigos de gráfico que devuelve esta función son simplemente números enteros a partir de 1000.

Ficheros FPG

Para incluir un gráfico que se ha realizado en el editor gráfico en un fichero FPG de debe arrastrar la ventana del gráfico a la ventana del fichero (pulsar en el gráfico, moverse hasta el fichero y soltar), entonces el programa pedirá el código del gráfico, con lo que se debe introducir aquí un número entero entre 1 y 999.

Para utilizar entonces el gráfico en un programa, se debe primero cargar el fichero FPG que lo contiene con la función load_fpg() y, después, asignar el código del gráfico a la variable graph.

Se muestra, a continuación, un ejemplo es necesario saber antes que un gráfico de una bola marrón se introdujo en el fichero HELP.FPG indicando el código de gráfico 100.

Programa ejemplo: 
PROGRAM ejemplo_graph;
BEGIN
    load_fpg("help\help.fpg");

    graph=100; // Se define el gráfico del proceso.

    LOOP
        x=mouse.x;
        y=mouse.y;
        FRAME;
    END
END


Se pueden cargar varios ficheros FPG en un programa; en ese caso se deberá indicar, además del código del gráfico en la variable local graph, el código de fichero que devuelve la función load_fpg() en la variable local file.

Si sólo se carga un fichero ésto no será necesario, ya que la variable file vale 0 por defecto en todos los procesos y 0 será siempre el código del primer fichero que se cargue en el programa.

Existen más variables locales relacionadas con el gráfico de un proceso, las principales son las siguientes:

  graph - Código del gráfico
  file - Código del fichero
  x, y - Coordenadas del gráfico
  z - Plano de profundidad
  angle - ángulo del gráfico
  size - Tamaño del gráfico
  flags - Espejados y transparencias
  region - Ventana de visualización

Ver: Datos locales